Como posso calcular linha na fórmula? fazendo um link para uma célula específica

0

Por exemplo: Link para a célula A1 é " =A1"
A - nome da coluna
1 - número da linha

Posso calcular o número da linha em fórmulas para criar links específicos?
Algo =A{some calculations}assim =A{1+1}será um link para Cell A2

microsoft-excel microsoft-excel-2013

— SavageStyle
fonte

0

Sim, mas isso é feito
=OFFSET(Start_Cell, Rows_Up_or_Down, Columns_Right_or_Left [, Number_of_Rows [, Number_of_Columns]])
Então, suponha que suas informações iniciem em C5 e você queira 1 célula abaixo de 4 linhas e 2 colunas à direita:
=OFFSET(C5,4,2)

— LDC3
fonte

0

Existem várias maneiras de fazer isso no Excel. A resposta do LDC3 descreve o OFFSET. Outra é:

    =INDIRECT(reference,style)

Isso cria uma referência a uma célula de uma entrada de texto. Isso proporciona muita liberdade para calcular ou criar uma referência de célula.

    =INDIRECT("A"&(1+1))   is equivalent to =A2
    =INDIRECT("A"&ROW())   if this formula is in cell C5, 
                           this would be equivalent to =A5

Se o parâmetro style for "TRUE" ou omitido, ele assumirá a formatação de referência de célula normal, como acima.

INDIRECT também permite um estilo diferente de especificação de linha e coluna. Se o parâmetro style for "FALSE", ele usa o local R#C#onde você usa a letra Rpara indicar que o próximo número é o número da linha e a letra Cpara indicar que o próximo número é o número da coluna (tudo é especificado como números). Se você omitir um número após o Rou C, ele assumirá que você quer dizer a linha ou coluna atual.

    =INDIRECT("R1C1",FALSE)    is equivalent to =A1
    =INDIRECT("R"&(ROW()-4)&"C",FALSE) if this formula is in cell C5, 
                                       this would be equivalent to =C1 
                                       (current column, and row number equal to 
                                        the current row -4).

Este formato permite calcular referências de linhas e colunas como números. Ele também funciona como OFFSET, mas em relação ao local atual em vez de uma célula âncora. Se você colocar o número entre colchetes, significa posição relativa (o número de linhas ou colunas longe da célula atual).

    =INDIRECT("R3C[-2]",FALSE)  if this formula is in cell C5, 
                                this would be equivalent to =A3

— fixador1234
fonte

0

=INDEX(A1:A100,1,2)       [this will give you row 1, column B]

OU

=INDEX(A1:Z100,1+1,2+2)   [this will give you row 2, column D]

= INDEX (TARGET:AREA, ROW, COLUMN)

Se você usa toneladas desses como eu faço. Os índices não ficam atrasados em seus documentos. Indireto e compensado consomem muito mais recursos. Arranque algumas milhares de indiretos ou offsets e seus documentos começarão a se arrastar com toda a volatilidade sendo atendida.

Obviamente, você pode embalá-lo de diferentes maneiras, tais como:

=INDEX(A1:Z100,ROW(A1)+1,COLUMN(B1)+2)

— helena4
fonte