Atalho do teclado para alternar entre folhas no Excel

O Excel 2007 possui um atalho de teclado que alterna entre planilhas?

Ctrl+ PgUppara mover para a esquerda.

Ctrl+ PgDnpara mover para a direita.

Macros VBA e atalho de teclado personalizado para ativar a primeira ou a última planilha

Se você deseja que um atalho de teclado real salte para a primeira ou a última planilha, coloque esse código em um módulo na pasta de trabalho "PESSOAL":

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

Vá para a guia Desenvolvedor> Macros. Navegue até essas macros (ToFirstSheet e ToLastSheet). Selecione um, clique em Opções e atribua um atalho de teclado. Faça o mesmo para o outro.

Salvando isso na pasta de trabalho "PESSOAL", ele estará disponível em qualquer arquivo do Excel.

Atalhos de teclado incorporados para ativar a planilha anterior ou a próxima

Para pular uma planilha para a esquerda ou direita, você pode usar estes atalhos de teclado padrão:

Ctrl+PgUp

Ctrl+PgDn

Macros VBA para ativar a planilha anterior ou seguinte

Veja como fazer o mesmo usando o VBA, tente o seguinte:

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

Funções VBA para retornar a planilha anterior ou seguinte

Use esta função se preferir obter o objeto da planilha anterior ou seguinte:

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

Use as funções como esta:

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub

Você também pode usar as teclas do acelerador para acessar a Gocaixa de diálogo. Você pode digitar algo comofoo!A1 navegar para a célula superior esquerda na planilha chamada "foo". Enquanto page up e page down são geralmente mais rápidas. Se você tiver um grande número (por exemplo, 20+) de folhas bem nomeadas, isso pode ser mais rápido. Ir também funciona bem se você tiver nomeado tabelas em suas planilhas.

Pressionar F5 normalmente abre a Gocaixa de diálogo.