Como uso a função AND e a função MATCH juntas para obter algo que não é "Não" e não foi retornado anteriormente

1

Eu tenho os seguintes dados e preciso retornar todos os valores que não são "Não". Ou seja, eu quero criar, em outra coluna, uma lista de todos os valores da coluna Eque não são "Não". Nunca haverá duplicatas nos dados originais (exceto as múltiplas repetições de "Não").

No minuto em que eu estou, pode obter o primeiro valor diferente de "Não". Estou tentando usar a função MATCH para retornar valores <> "No" AND <> [valores nas células anteriores].

Eu tenho a seguinte fórmula na célula L12

{=INDEX($E$5:$E$12,AND(MATCH(TRUE,$E$5:$E$12<>"No"),MATCH(TRUE,$E$5:$E$12<>$L$5:L11)),0)}

Alguém tem alguma ideia?

microsoft-excel worksheet-function

— John
fonte

Qual é o problema com sua fórmula existente? Você espera ter réplicas nos dados originais (por exemplo, "J2" duas vezes)?

— Máté Juhász

Após o primeiro resultado, ele retornará "Não" Aqui está a fórmula para o 1º resultado: = {ÍNDICE (E5: E11, CORRESPONDÊNCIA (VERDADEIRO, E5: E11 <> "Não", 0))} Basicamente, quero que ele retorne IC3 na primeira célula, J1 na cela ao lado, então J2 na célula depois que ect ect ....

— John

E nunca haverá repetições no :) de dados original

— John

0

Com os dados de A1 a A14 , em B1, digite:

=IF(A1="No","",A1)

e copie. Em C1, digite a Fórmula da matriz :

=IFERROR(INDEX($B$1:$B$14,SMALL((IF(LEN($B$1:$B$14),ROW(INDIRECT("1:"&ROWS($B$1:$B$14))))),ROW(A1)),1),"")

e copie. Por exemplo:

— Aluno de Gary
fonte

Cara, você é um gênio! Quando vejo que muitos suportes em uma fórmula do excel eu sei que algum poder cerebral sério está acontecendo lá. Faz exatamente o que eu precisava :) Obrigado cara, você é demais!

— John

0

Coloque esta fórmula, usada para determinar o número esperado de retornos, por exemplo, L1:

=COUNTIF($E$5:$E$12,"<>No")

Então, esta fórmula em sua primeira célula de escolha:

=IF(ROWS($1:1)>$L$1,"",INDEX($E:$E,AGGREGATE(15,6,ROW(E$5:E$12)/(E$5:E$12<>"No"),ROWS($1:1))))

(Você precisará de uma pequena modificação se estiver usando uma versão anterior ao 2010 do Excel.)

Copie esta fórmula para baixo (embora não a de L1) até começar a receber espaços em branco para os resultados.

Saudações

— XOR LX
fonte

0

Aqui está um que não requer uma coluna auxiliar. Supondo que seus dados iniciem em A1:

=IFERROR(INDEX(A$1:A$14,SMALL(IF(A$1:A$14<>"No",ROW(A$1:A$14)-MIN(ROW(A$1:A$14))+1,""),ROW())),"")

Confirme como uma fórmula de matriz com ctrl + shift + enter e preencha automaticamente. Do jeito que está escrito, ele deve começar na primeira linha, mas você pode ajustar o último ROW () para começar em outro lugar, se precisar.

— Kyle
fonte