Vim, comentário sensível ao contexto / comportamento de não comentário

Eu edito muito código PHP com o Vim e encontrei um problema com algumas macros no meu .vimrc.

Atualmente, uso essas duas macros para comentar / descomentar no estilo C

"c-style (//) comment (press the [.] key)
au FileType php vnoremap . :s/^\(\s*\)\(.\+\)$/\1\/\/\2/<CR>:noh<CR>gv
"c-style (//) uncomment (press the [,] key)
au FileType php vnoremap , :s/^\(\s*\)\/\//\1/<CR>:noh<CR>gv

E esses dois para comentar / descomentar no estilo HTML

"html-style (<!-- -->) comment (press the [.] key)
au FileType html vnoremap . :s/^\(\s*\)\(.\+\)$/\1<!-- \2 -->/g<CR>:noh<CR>gv
"html-style (<!-- -->) uncomment (press the [,] key)
au FileType html vnoremap , :s/^\(\s*\)<!-- \(.*\) -->/\1\2/g<CR>:noh<CR>gv

Essas macros funcionam bem quando aplicadas ao tipo de arquivo pretendido, mas como geralmente há HTML incorporado em um arquivo PHP, o estilo de comentários do PHP é inútil.

Existe uma maneira de o Vim detectar se está funcionando em um pedaço de código HTML dentro de um arquivo PHP e aplicar o comportamento correto de comentários?

Edit: Eu sei que posso definir manualmente o tipo de arquivo e que existem plugins disponíveis para isso. Eu estava procurando aprender mais sobre como escrever macros melhores.

Para fazer o que você deseja, não há realmente nenhuma maneira de contornar a escrita de uma função e o mapeamento de suas teclas preferidas.

Para começar :echo synIDattr(synID(line("."), col("."), 1), "name"), imprima o nome do grupo de destaque da palavra atual sob o cursor.

Você pode usar essas informações para determinar qual estilo de comentário usar.

Um exemplo aproximado para você começar:

function! s:MyComment () range
    for i in range(a:firstline, a:lastline)
        exe "normal " . i . "gg"
        normal ^
        let stuff = synIDattr(synID(line("."), col("."), 1), "name")
        if strpart(stuff, 0, 4) == "html"
            normal I<!-- 
            normal A -->
        else
            normal I//
        endif
    endfor
endfunction
vmap <silent> . :call <SID>MyComment()<CR>

Caso você possa aceitar escolher manualmente o tipo de comentário que deseja usar, eu recomendaria esta dica .

Você teria 4 combinações para lembrar:

C-style:
,* comment  
,c uncomment

HTML style: 
,< comment 
,d uncomment