Junte dois arquivos com colunas correspondentes

11

Arquivo1.txt

    id                            No
    gi|371443199|gb|JH556661.1| 7907290
    gi|371443198|gb|JH556662.1| 7573913
    gi|371443197|gb|JH556663.1| 7384412
    gi|371440577|gb|JH559283.1| 6931777

Arquivo2.txt

 id                              P       R       S
 gi|367088741|gb|AGAJ01056324.1| 5       5       0
 gi|371443198|gb|JH556662.1|     2       2       0
 gi|367090281|gb|AGAJ01054784.1| 4       4       0
 gi|371440577|gb|JH559283.1|     21      19      2

output.txt

 id                              P       R       S  NO
 gi|371443198|gb|JH556662.1|     2       2       0  7573913
 gi|371440577|gb|JH559283.1|     21      19      2  6931777

O arquivo1.txt possui duas colunas e o arquivo2.txt possui quatro colunas. Eu quero unir os dois arquivos que possuem um ID exclusivo (o array [1] deve corresponder nos dois arquivos (arquivo1.txt e arquivo2.txt)) e fornecer apenas a identificação correspondente à saída (consulte output.txt).

Eu tentei join -v <(sort file1.txt) <(sort file2.txt). Qualquer ajuda com os comandos awk ou join solicitados.

awk join

— jack
fonte

18

join funciona bem:

$ join <(sort File1.txt) <(sort File2.txt) | column -t | tac
 id                           No       P   R   S
 gi|371443198|gb|JH556662.1|  7573913  2   2   0
 gi|371440577|gb|JH559283.1|  6931777  21  19  2

ps. a ordem da coluna de saída é importante?

se sim, use:

$ join <(sort 1) <(sort 2) | tac | awk '{print $1,$3,$4,$5,$2}' | column -t
 id                           P   R   S  No
 gi|371443198|gb|JH556662.1|  2   2   0  7573913
 gi|371440577|gb|JH559283.1|  21  19  2  6931777

— pressa
fonte

funciona bem. a ordem das colunas não importa

— jack

Qual o motivo da inclusão tac?

— Michael Mrozek

Isso ocorre porque sortcoloca a sequência do cabeçalho no final. Na verdade, é uma solução suja. E, em geral, o cabeçalho do caso pode ir para o meio da saída. No entanto, funciona aqui.

— apressar

10

Uma maneira de usar awk:

Conteúdo de script.awk:

## Process first file of arguments. Save 'id' as key and 'No' as value
## of a hash.
FNR == NR {
    if ( FNR == 1 ) { 
        header = $2
        next
    }   
    hash[ $1 ] = $2
    next
}

## Process second file of arguments. Print header in first line and for
## the rest check if first field is found in the hash.
FNR < NR {
    if ( $1 in hash || FNR == 1 ) { 
        printf "%s %s\n", $0, ( FNR == 1 ? header : hash[ $1 ] ) 
    }   
}

Execute-o como:

awk -f script.awk File1.txt File2.txt | column -t

Com o seguinte resultado:

id                           P   R   S  NO
gi|371443198|gb|JH556662.1|  2   2   0  7573913
gi|371440577|gb|JH559283.1|  21  19  2  6931777

— Birei
fonte

+65535 para manter a ordem da linha original. :-)

— zeekvfu

+65535 para manter a ordem da linha original. :-)

— zeekvfu