Um melhor comando de colar

Eu tenho os dois arquivos a seguir (preenchi as linhas com pontos para que todas as linhas de um arquivo tenham a mesma largura e tornei file1 todas maiúsculas para torná-lo mais claro).

contents of file1:

ETIAM......
SED........
MAECENAS...
DONEC......
SUSPENDISSE

contents of file2

Lorem....
Proin....
Nunc.....
Quisque..
Aenean...
Nam......
Vivamus..
Curabitur
Nullam...

Observe que o arquivo2 é maior que o arquivo1.

Quando eu executo este comando:

paste file1 file2

Eu recebo essa saída

ETIAM...... Lorem....
SED........ Proin....
MAECENAS... Nunc.....
DONEC...... Quisque..
SUSPENDISSE Aenean...
    Nam......
    Vivamus..
    Curabitur
    Nullam...

O que posso fazer para que a saída seja a seguinte?

ETIAM...... Lorem....
SED........ Proin....
MAECENAS... Nunc.....
DONEC...... Quisque..
SUSPENDISSE Aenean...
            Nam......
            Vivamus..
            Curabitur
            Nullam...

eu tentei

paste file1 file2 | column -t

mas faz isso:

ETIAM......  Lorem....
SED........  Proin....
MAECENAS...  Nunc.....
DONEC......  Quisque..
SUSPENDISSE  Aenean...
Nam......
Vivamus..
Curabitur
Nullam...

não tão feia quanto a saída original, mas incorreta em colunas.

Supondo que você não tenha caracteres de tabulação em seus arquivos,

paste file1 file2 | expand -t 13

com o arg para -tescolher adequadamente para cobrir a largura máxima desejada da linha no arquivo1.

O OP adicionou uma solução mais flexível:

Eu fiz isso para que funcione sem o número mágico 13:

paste file1 file2 | expand -t $(( $(wc -L <file1) + 2 ))

Não é fácil digitar, mas pode ser usado em um script.

Eu pensei que o awk poderia fazer isso muito bem, então pesquisei "awk reading input from two files" e encontrei um artigo sobre o stackoverflow para usar como ponto de partida.

Primeiro é a versão condensada, depois totalmente comentada abaixo. Demorou mais do que alguns minutos para resolver. Eu ficaria feliz com alguns aprimoramentos de pessoas mais inteligentes.

awk '{if(length($0)>max)max=length($0)}
FNR==NR{s1[FNR]=$0;next}{s2[FNR]=$0}
END { format = "%-" max "s\t%-" max "s\n";
  numlines=(NR-FNR)>FNR?NR-FNR:FNR;
  for (i=1; i<=numlines; i++) { printf format, s1[i]?s1[i]:"", s2[i]?s2[i]:"" }
}' file1 file2

E aqui está a versão totalmente documentada do acima.

# 2013-11-05 mike@diehn.net
# Invoke thus:
#   awk -f this_file file1 file2
# The result is what you asked for and the columns will be
# determined by input file order.
#----------------------------------------------------------
# No matter which file we're reading,
# keep track of max line length for use
# in the printf format.
#
{ if ( length($0) > max ) max=length($0) }

# FNR is record number in current file
# NR is record number over all
# while they are equal, we're reading the first file
#   and we load the strings into array "s1"
#   and then go to the "next" line in the file we're reading.
FNR==NR { s1[FNR]=$0; next }

# and when they aren't, we're reading the
#   second file and we put the strings into
#   array s2
{s2[FNR]=$0}

# At the end, after all lines from both files have
# been read,
END {
  # use the max line length to create a printf format
  # the right widths
  format = "%-" max "s\t%-" max "s\n"
  # and figure the number of array elements we need
  # to cycle through in a for loop.
  numlines=(NR-FNR)>FNR?NR-FNR:FNR;
  for (i=1; i<=numlines; i++) {
     printf format, s1[i]?s1[i]:"", s2[i]?s2[i]:""
  }
}

Não é uma solução muito boa, mas consegui fazer isso usando

paste file1 file2 | sed 's/^TAB/&&/'

onde TAB é substituído pelo caractere de tabulação.

No Debian e derivativos, columntem uma opção -n nomerge que permite que a coluna faça a coisa certa com campos vazios. Internamente, columnusa a wcstok(wcs, delim, ptr)função, que divide uma cadeia de caracteres ampla em tokens delimitados pelos caracteres largos no delimargumento.

wcstokcomeça pulando caracteres largos delimantes de reconhecer o token. A -nopção usa um algoritmo que não ignora caracteres largos iniciais delim.

Infelizmente, isso não é muito portátil: -né específico do Debian e columnnão está no POSIX, é aparentemente uma coisa do BSD.

Retirando os pontos que você usou para preenchimento:

file1:

ETIAM
SED
MAECENAS
DONEC
SUSPENDISSE

arquivo2:

Lorem
Proin
Nunc
Quisque
Aenean
Nam
Vivamus
Curabitur
Nullam

Tente o seguinte:

$ ( echo ".TS"; echo "l l."; paste file1 file2; echo ".TE" ) | tbl | nroff | more

E você receberá:

ETIAM         Lorem
SED           Proin
MAECENAS      Nunc
DONEC         Quisque
SUSPENDISSE   Aenean
              Nam
              Vivamus
              Curabitur
              Nullam

Uma awksolução que deve ser razoavelmente portátil e deve funcionar para um número arbitrário de arquivos de entrada:

# Invoke thus:
#   awk -F\\t -f this_file file1 file2

# every time we read a new file, FNR goes to 1

FNR==1 {
    curfile++                       # current file
}

# read all files and save all the info we'll need
{
    column[curfile,FNR]=$0          # save current line
    nlines[curfile]++               # number of lines in current file
    if (length > len[curfile])
            len[curfile] = length   # max line length in current file
}

# finally, show the lines from all files side by side, as a table
END {
    # iterate through lines until there are no more lines in any file
    for (line = 1; !end; line++) {
            $0 = _
            end = 1

            # iterate through all files, we cannot use
            #   for (file in nlines) because arrays are unordered
            for (file=1; file <= curfile; file++) {
                    # columnate corresponding line from each file
                    $0 = $0 sprintf("%*s" FS, len[file], column[file,line])
                    # at least some file had a corresponding line
                    if (nlines[file] >= line)
                            end = 0
            }

            # don't print a trailing empty line
            if (!end)
                    print
    }
}