Sou fã da maneira como o Atom e o Sublime Text lidam com a dobra de linhas, onde a primeira linha de cada dobra é visível (completa com destaque de sintaxe) e um marcador é anexado ao final da linha que indica a dobra.

Veja a captura de tela abaixo comparando a dobradura de travessão do Vim (em cima) com a do Atom (em baixo):

O Vim dedica duas linhas para cada dobra. A primeira linha serve como cabeçalho e a segunda linha descreve algumas informações sobre a dobra (número de linhas e texto dentro da dobra).

O Atom usa apenas uma linha e usa um pequeno marcador no final da linha para indicar a dobra, juntamente com a cor adicionada aos números de linha à esquerda. O estilo dobrável do Atom usa menos espaço na tela, mas ainda comunica todas as informações que realmente preciso.

Sou parcial com o estilo de dobramento Atom. Parece mais limpo e consistente, na minha opinião, principalmente ao listar vários métodos ou atributos em uma linha (como na captura de tela acima).

Existe uma maneira de aproximar aproximadamente o estilo de dobramento do Atom no Vim?

Duas linhas vs. uma linha

No Vim, todas as linhas dentro de uma dobra serão recolhidas em uma única linha, e a 'foldtext'opção determina a sinopse dessas linhas (geralmente traços, o número de linhas dobradas e o conteúdo das primeiras (ou todas) linhas).

No seu exemplo, no Vim, apenas o {...}próprio bloco de parâmetros é dobrado; a linha acima (que usa os parâmetros) não faz parte da dobra. Por outro lado, no outro editor, essa linha usando os parâmetros pertence à dobra e seu texto da dobra (para usar a terminologia do Vim) é o conteúdo dessa linha mais o marcador anexado.

Adaptação

No Vim, as dobras podem ser geradas por diferentes meios (consulte :help fold-methods) e dependem 'filetype'do buffer. A dificuldade de incluir a linha acima na dobra depende disso; verifique com :setlocal foldmethod?. Com a dobradura de indentação , não há nada que você possa influenciar; você precisa mudar para outro método. Para dobrar sintaxe , isso significaria adaptar as definições de sintaxe e poderia ser muito complicado. Você terá mais sorte se uma expressão for usada, mas isso ainda significaria entender e alterar a lógica. (É improvável que o autor do plugin do tipo de arquivo tenha fornecido uma configuração para influenciar isso.)

Destaque de sintaxe da linha dobrada

Infelizmente, isso não é possível. O Vim sempre usa o Foldedgrupo de destaque para toda a linha dobrada. Você pode ajustá-lo através de :highlightcomandos no seu ~/.vimrc, mas a diferenciação individual da sintaxe será perdida.

O Vim já exibe dobras como uma única linha. No entanto, nas indentdobras de Vim , todas as linhas que têm o mesmo recuo são incluídas em uma dobra. Portanto, na sua captura de tela, as linhas às quais você se refere como "cabeçalhos" (por exemplo, a que está começando collection_base_url) não estão dentro das dobras.

Você pode obter algo semelhante à dobra do Atom usando o Vim foldexpr foldmethod:

" Finds the indent of a line. The indent of a blank line is the indent of the
" first non-blank line above it.
function! FindIndent(line_number, indent_width)
    " Regular expression for a "blank" line
    let regexp_blank = "^\s*$"

    let non_blank_line = a:line_number
    while non_blank_line > 0 && getline(non_blank_line) =~ regexp_blank
        let non_blank_line = non_blank_line - 1
    endwhile
    return indent(non_blank_line) / a:indent_width
endfunction

" 'foldexpr' for Atom-style indent folding
function! AtomStyleFolding(line_number)
    let indent_width = &shiftwidth

    " Find current indent
    let indent = FindIndent(a:line_number, indent_width)

    " Now find the indent of the next line
    let indent_below = FindIndent(a:line_number + 1, indent_width)

    " Calculate indent level
    if indent_below > indent
        return indent_below
    elseif indent_below < indent
        return "<" . indent
    else
        return indent
    endif
endfunction

set foldexpr=AtomStyleFolding(v:lnum)
set foldmethod=expr

Isso define uma expressão de dobra (consulte :help fold-expr) da seguinte maneira:

• Para linhas imediatamente anteriores às linhas recuadas, ele retorna o recuo do bloco a seguir.
• Para linhas recuadas, ele retorna o recuo. (Dividido pela largura de turno para que cada nível de recuo aumente o valor retornado em 1)
• Para linhas no final de um bloco de linhas recuadas, ele retorna uma string "<N", onde N é definido como recuo. Isso diz ao Vim que uma dobra do nível N termina nessa linha.

Atualizar

@alxndr pergunta nos comentários se é possível estender isso para incluir os ends ultrapassados ​​de Ruby dentro das dobras. Você pode começar substituindo a " Calculate indent levelseção pelo seguinte:

if indent_below > indent
    return indent_below
elseif getline(a:line_number) =~ '^\s*end\s*$'
    return "<" . (indent + 1)
else
    return indent
endif

Como é, essa não é a solução mais robusta (por exemplo, ela falhará se a endinstrução estiver na mesma linha, após ponto e vírgula). Você pode ajustar a expressão regular e o código ao redor para resolver isso, mas como agora você está analisando a sintaxe real do arquivo, suspeito que as coisas possam ficar muito mais complicadas antes de você ter uma boa solução.