Como alterar a granularidade de desfazer no Vim?

Em algum momento, meu Vim desfiz uma palavra inteira quando eu batesse u.

[i]typing some words[C-c][u]

Resultaria em

typing some

No entanto, a granularidade de desfazer parece ter sido alterada para excluir uma letra de cada vez.

[i]typing some words[C-c][u]

Resulta em

typing some word

Lembro-me de ler algo sobre como personalizar a granularidade de desfazer no Practical Vim, mas não consigo me lembrar de como controlá-lo. Qualquer ajuda apreciada!

Quebrando manualmente a sequência de desfazer

Você pode interromper manualmente a sequência de desfazer no modo Inserir com <C-G>u. Da ajuda :

CTRL-G u        break undo sequence, start new change

Exemplo

iHello<C-G>u world!<Esc>u

Isso deixará você com o texto

Hello

Divisão de comandos

i                           " Enter Insert mode
 Hello                      " Type 'Hello'
      <C-G>u                " Break the undo sequence
             world!         " Type ' world!'
                   <Esc>    " Return to Normal mode
                        u   " Undo

Solução automática

Controle de nível inferior de granulação mais fina

Aqui está um pequeno trecho do VimScript usado <C-G>upara criar quebras de desfazer quando você começa a excluir texto e também quando você começa a inserir texto novamente após uma exclusão.

function! s:start_delete(key)
    let l:result = a:key
    if !s:deleting
        let l:result = "\<C-G>u".l:result
    endif
    let s:deleting = 1
    return l:result
endfunction

function! s:check_undo_break(char)
    if s:deleting
        let s:deleting = 0
        call feedkeys("\<BS>\<C-G>u".a:char, 'n')
    endif
endfunction

augroup smartundo
    autocmd!
    autocmd InsertEnter * let s:deleting = 0
    autocmd InsertCharPre * call s:check_undo_break(v:char)
augroup END

inoremap <expr> <BS> <SID>start_delete("\<BS>")
inoremap <expr> <C-W> <SID>start_delete("\<C-W>")
inoremap <expr> <C-U> <SID>start_delete("\<C-U>")

Notas

Isto irá funcionar para <BS>, <C-W>(excluir uma palavra), e <C-U>(excluir para o início da linha). Se houver mais maneiras de excluir no modo Inserir, elas poderão ser suportadas adicionando inoremapchamadas adicionais no final.