Copie o original ao arrastar um alias

Eu tenho uma pasta cheia com alias de todos os lugares no meu sistema. Agora, quero fornecer exatamente esses arquivos como originais para um disco rígido externo ou o que mais.

Existe uma maneira de simplesmente pegar esses apelidos e copiar seus originais em uma segunda pasta?

Reunimos um pouco de AppleScript para você. Se você usar o Editor de scripts para salvá-lo como um applet, poderá arrastar e soltar pastas nele. O script primeiro solicitará a pasta de destino e depois examinará as pastas descartadas em busca de aliases contidos. Se encontrar algum, copiará os itens originais para a pasta de destino especificada.

Aqui está o código:

on open droppedItems
    try
        set destinationFolder to choose folder with prompt "Select destination folder:"
    on error
        return
    end try

    repeat with itemCount from 1 to length of droppedItems
        set theFolder to item itemCount of droppedItems

        tell application "Finder"
            if folder (theFolder as string) exists then
                set folderItems to list folder theFolder without invisibles

                repeat with folderItemCount from 1 to length of folderItems
                    set filename to (item folderItemCount of folderItems)
                    set theAlias to ((theFolder as text) & filename) as alias
                    try
                        set originalFile to original item of theAlias -- is Finder alias?
                        duplicate originalFile to destinationFolder
                    on error
                        display dialog (theAlias as string) & " doesn't seem to be an alias. Skipping."
                    end try
                end repeat
            else
                display dialog (theFolder as string) & "is not a folder. Skipping."
            end if
        end tell
    end repeat
end open

Não é bonito nem completo, mas visa mostrar um caminho possível. I. e. não atravessa nenhuma subpasta. Além disso, não há verificação da existência do arquivo antes de copiar. De qualquer forma, ainda pode ser o que você precisa. Diverta-se!